ArduinoJson 라이브리 사용

ArduinoJson

이 문서에서는 네트워크 통신에서 JSON을 사용하기 위한 라이브러리인 ArduinoJson을 설치하고 사용하는 방법에 대해서 다룬다.

설치

툴 → 라이브러리 관리 메뉴를 실행한다.

ArduinoJson 라이브러리를 찾아 설치한다. 베타버전을 설치하지 않도록 주의한다.

사용법

ArduinoJson을 이용하여 JSON 문자열을 생성하거나 분석할 수 있다.

• Documentation

• 생성 도우미 사이트

JSON 생성

JSON을 생성하는 과정은 다음과 같다.

1. JSON Object 크기 설정

2. StaticJsonDocument/DynamicJsonDocument 생성

3. 데이터 설정

4. 문자열로 변환

크기 설정

만들어질 JSON Object의 모양이 다음과 같다고 가정한다.

{
    "no":1,
    "name":"홍길동",
    "age":20
}

만들어질 JSON은 3개의 필드를 가지므로 다음과 같이 크기를 설정할 수 있다.

const int capacity = JSON_OBJECT_SIZE(3);

JsonDocument 생성

계산한 크기(byte)를 이용하여 JsonDocument 객체를 생성한다. StaticJsonDocument와 DynamicJsonDocument 중에서 선택이 가능하며, 공식 문서에 따르면 다음과 같은 특징을 가진다.

• StaticJsonDocument : 스택 메모리에 저장되며 1KB 미만의 데이터에 권장

• DynamicJsonDocument : 힙 메모리에 저장되며 1KB 이상의 데이터에 권장

StaticJsonDocument<capacity> doc;

생성하며 크기를 지정해준다.

데이터 설정

생성한 JsonDocument에 데이터를 설정한다. key-value형태로 설정해야 하므로 다음과 같이 작성한다.

//doc["key"]=value;
doc["no"] = 1;
doc["name"] = "홍길동";
doc["age"] = 20;

문자열 변환

생성한 JsonDocument를 문자열로 변환하기 위한 문자열 변수를 생성한다.

String result;

생성한 문자열을 이용하여 변환 명령을 사용한다.

serializeJson(doc, result);

출력을 통해 확인해본다.

Serial.println(result);

샘플 코드

종합한 샘플 코드는 다음과 같다. ArduinoJson.h를 include 해야 정상적으로 실행된다.

#include <ArduinoJson.h>

void setup() {
  Serial.begin(9600);
  const int capacity = JSON_OBJECT_SIZE(3);
  StaticJsonDocument<capacity> doc;
  doc["no"] = 1;
  doc["name"] = "홍길동";
  doc["age"] = 20;
  String result;
  serializeJson(doc, result);
  Serial.println(result);

  while(1){
    delay(10);
  }
}

void loop() {
  
}

JSON 해석

JSON string을 해석하기 위한 구현 순서는 다음과 같다.

1. Json String 준비

2. JsonDocument 생성

3. 데이터 변환

4. 데이터 추출

Json String 준비

해석할 Json String을 준비한다. 직접 만들어도 되고, 파일이나 네트워크를 통해 읽을 수도 있다.

String jsonStr = "{\"no\":1,\"name\":\"홍길동\",\"age\":20}";

JsonDocument 준비

StaticJsonDocument 또는 DynamicJsonDocument 중 하나를 준비한다. 이 문서에서는 StaticJsonDocument를 준비했다.

우선 Json의 형태를 알고 있기 때문에 크기를 계산한다.

const int capacity = JSON_OBJECT_SIZE(3) + 60;

계산된 크기를 이용하여 StaticJsonDocument를 생성한다.

StaticJsonDocument<capacity> doc;

데이터 변환

deserializeJson 함수를 이용하여 변환한다.

//deserializeJson(JsonDocument, String);
deserializeJson(doc, jsonStr);

데이터 추출

데이터를 추출할 때는 key를 사용하며, .as()를 이용하여 데이터 형태를 지정해야 한다.

doc["no"].as<int>()
doc["name"].as<String>()
doc["age"].as<int>()

샘플 코드

종합한 샘플 코드는 다음과 같다. ArduinoJson.h를 include 해야 정상적으로 실행된다.

#include <ArduinoJson.h>

void setup() {
  Serial.begin(9600);

  String jsonStr = "{\"no\":1,\"name\":\"홍길동\",\"age\":20}";

  const int capacity = JSON_OBJECT_SIZE(3) + 60;
  StaticJsonDocument<capacity> doc;

  deserializeJson(doc, jsonStr);

  Serial.print("no = "); Serial.println(doc["no"].as<int>());
  Serial.print("name = "); Serial.println(doc["name"].as<String>());
  Serial.print("age = "); Serial.println(doc["age"].as<int>());

  while(1){
    delay(10);
  }
}

void loop() {

}